symbol aantal_metingen = 127

symbol aantal_gemeten = b2
symbol teller = b0
symbol lichtwaarde = b3
symbol temperatuurwaarde = b4
symbol opslag_wijzer = b1

symbol teller_w = w3

symbol lichtpin = 0
symbol temperatuurpin = 1
symbol keuzepin = pin7

symbol leds_uit = %00000000
symbol leds_aan = %11100000
symbol rood_aan = %00100000

klaarzetten:
	let opslag_wijzer = 0
	let pins = leds_aan
	nap 7
	let pins = leds_uit

basis: 
	if keuzepin = 1 then oversturen
meten:
 	gosub signaal_meting
	for aantal_gemeten = 1 to aantal_metingen
		pulsout 7, 10000
		gosub licht_meten
		gosub temp_meten
		gosub licht_opslaan
		gosub temp_opslaan
		gosub pauzeren
	next
		gosub meting_klaar
	end


oversturen:
	gosub signaal_versturen
	gosub signaal_versturing 
	end

;========================================
;========================================



signaal_meting:
	for teller = 1 to 10
		let pins = leds_aan
		nap 5
		let pins = leds_uit
		nap 5
	next
	return

signaal_versturen:
	for teller = 1 to 5
		let pins = rood_aan
		nap 5
		let pins = leds_uit
		nap 5
	next
	return


licht_meten:
	readadc lichtpin, lichtwaarde
	let lichtwaarde = 255 - lichtwaarde
	return


temp_meten:
	readadc temperatuurpin, temperatuurwaarde
	let temperatuurwaarde = 255 - temperatuurwaarde
	return


licht_opslaan:
	write opslag_wijzer, lichtwaarde
	let opslag_wijzer = opslag_wijzer + 1
	return

temp_opslaan:
	write opslag_wijzer, temperatuurwaarde
	let opslag_wijzer = opslag_wijzer + 1
	return

pauzeren:
	
	for teller = 1 to 78
		pulsout 6, 10000
		sleep 10
	next
	sleep 1
	return

signaal_versturing:
	sleep 1
	sertxd("lichtwaarde: ","tempwaarde:", 13, 10)
	for teller = 1 to aantal_metingen
		read opslag_wijzer, lichtwaarde
		let opslag_wijzer = opslag_wijzer + 1
		read opslag_wijzer, temperatuurwaarde
		let opslag_wijzer = opslag_wijzer + 1
		sertxd(#lichtwaarde," ",#temperatuurwaarde, 13, 10)
	next
	return


meting_klaar:
	for teller_w = 1 to 500
		high 5
		nap 3
		low 5
		nap 6
	next
	return