symbol number_of_measurements = 127

symbol number_measured = b2
symbol counter = b0
symbol light_value = b3
symbol temp_value = b4
symbol storage_pointer = b1

symbol counter_w = w3

symbol light_inputpin = 0
symbol temp_inputpin = 1
symbol measure_or_send_inputpin = pin7

symbol leds_off = %00000000
symbol leds_on = %11100000
symbol red_led_on = %00100000


initialize:
	let storage_pointer = 0
	let pins = leds_on
	nap 7
	let pins = leds_off
main: 
	if measure_or_send_inputpin = 1 then send_results
measurements:
 	gosub signal_start_measurements
	for number_measured = 1 to number_of_measurements
		pulsout 7, 10000
		gosub measure_light
		gosub measure_temp
		gosub store_light_in_eeprom
		gosub store_temp_in_eeprom
		gosub pause_interval
	next
	gosub signal_measurements_finished
	end

send_results:
	gosub signal_send_measurements
	gosub send_measurements  
	end

;========================================
;========================================



signal_start_measurements:
	for counter = 1 to 10
		let pins = leds_on
		nap 5
		let pins = leds_off
		nap 5
	next
	return

signal_send_measurements:
	for counter = 1 to 5
		let pins = red_led_on
		nap 5
		let pins = leds_off
		nap 5
	next
	return


measure_light:
	readadc light_inputpin, light_value
	let light_value = 255 - light_value
	return


measure_temp:
	readadc temp_inputpin, temp_value
	let temp_value = 255 - temp_value
	return


store_light_in_eeprom:
	write storage_pointer, light_value
	let storage_pointer = storage_pointer + 1
	return

store_temp_in_eeprom:
	write storage_pointer, temp_value
	let storage_pointer = storage_pointer + 1
	return

pause_interval:
	for counter = 1 to 78
		pulsout 6, 10000
		sleep 10
	next
	sleep 1
	return

send_measurements:
	sleep 1
	sertxd("light_value: ","temp_value:", 13, 10)
	for counter = 1 to number_of_measurements
		read storage_pointer, light_value
		let storage_pointer = storage_pointer + 1
		read storage_pointer, temp_value
		let storage_pointer = storage_pointer + 1
		sertxd(#light_value," ",#temp_value, 13, 10)
	next
	return


signal_measurements_finished:
	for counter_w = 1 to 500
		high 5
		nap 3
		low 5
		nap 6
	next
	return